The other day I sat in on an online dotBrighton talk on openFrameworks by James Alliban. One of the things he happened to mention in the hour or so long talk, was Graffiti Markup Language. Now this wasn’t the first I’d heard of the subject – I heard the term before in a session at some conference or other. On average, as my wife will attest to, I’d say I have to hear things 2 or 3 times before I start to listen. In any case, I took this recent exposure to the term as an excuse to actually do some googling and see what it’s all about.
For anyone who doesn’t know, Graffiti Markup Language (or GML) is basically just a structured xml format used “for archiving gestural graffiti motion data into a text file.” In a nutshell, gml contains a whole slew of pt (‘point’) nodes and the amount of time it takes to get from one of those nodes to the next. Each point represents a x, y, z coordinate of an end stroke of a graffiti tag.
So, just for kicks, I strolled over to this joint, downloaded 6 .gml files and started fooling around with Seb Lee-Delisle’s Graphics3D and my own Bayer Mosaic PixelBender filter and came up with the little thing below. It just loops through the 6 tags, drawing them out in 3D. Just an interesting way of looking at graffiti and killing a Friday lunch hour. Mouse around to rotate the object.
[kml_flashembed publishmethod=”static” fversion=”10.0.0″ movie=”https://blog.onebyonedesign.com/wp-content/uploads/2010/10/gml.swf” width=”600″ height=”400″ targetclass=”flashmovie”]
[/kml_flashembed]
For those interested, the entire script is posted down below.
/**
* Copyright (c) 2010 Devon O. Wolfgang
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in
* all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
* THE SOFTWARE.
*/
package {
import com.bit101.components.PushButton;
import com.bit101.components.Style;
import com.greensock.TweenNano;
import com.sebleedelisle.draw3d.Graphics3D;
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BlendMode;
import flash.display.Shader;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.filters.BlurFilter;
import flash.filters.ShaderFilter;
import flash.geom.ColorTransform;
import flash.geom.Point;
import flash.utils.ByteArray;
/**
* Graffiti in 3 dimensions...
* @author Devon O.
*/
[SWF(width='600', height='400', backgroundColor='#000000', frameRate='31')]
public class Main extends Sprite {
[Embed(source = '../assets/20218.gml', mimeType = 'application/octet-stream')] public static const GML1:Class;
[Embed(source = '../assets/20220.gml', mimeType = 'application/octet-stream')] public static const GML2:Class;
[Embed(source = '../assets/20221.gml', mimeType = 'application/octet-stream')] public static const GML3:Class;
[Embed(source = '../assets/20223.gml', mimeType = 'application/octet-stream')] public static const GML4:Class;
[Embed(source = '../assets/20224.gml', mimeType = 'application/octet-stream')] public static const GML5:Class;
[Embed(source = '../assets/20226.gml', mimeType = 'application/octet-stream')] public static const GML6:Class;
[Embed(source = '../assets/Bayer.pbj', mimeType = 'application/octet-stream')] public static const BAYER:Class;
private var _gmlNodes:XMLList;
private var _graffiti:Vector.;
private var _colors:Vector.;
private var _running:Boolean = false;
private var _pt:Point = new Point();
private var _g3d:Graphics3D;
private var _currentPoint:int = 0;
private var _currentTag:int = 0;
private var _zpos:Number = -20;
private var _tweenobject:Object = { x:0, y:0, z:0 };
private var _mult:Number = 120.0;
private var _data:BitmapData;
private var _s:Sprite;
private var _blur:BlurFilter = new BlurFilter(16, 16, 3);
private var _darken:ColorTransform = new ColorTransform(1, 1, 1, .5, 0, 0, 0, -100);
private var _bayer:ShaderFilter;
public function Main():void {
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
private function init(event:Event = null):void {
removeEventListener(Event.ADDED_TO_STAGE, init);
_data = new BitmapData(stage.stageWidth, stage.stageHeight, false, 0x000000);
addChild(new Bitmap(_data));
initFilter();
initTags();
initGraphics();
nextTag();
initStartButton();
}
private function initFilter():void {
var shader:Shader = new Shader(new BAYER() as ByteArray);
shader.data.size.value = [200];
_bayer = new ShaderFilter(shader);
}
private function initStartButton():void {
Style.BUTTON_FACE = 0x000000;
var sb:PushButton = new PushButton(this, 5, 5, "Start", toggleAction);
sb.toggle = true;
}
private function toggleAction(event:MouseEvent):void {
if (willTrigger(Event.ENTER_FRAME)) {
removeEventListener(Event.ENTER_FRAME, onFrame);
event.currentTarget.label = "Start";
_running = false;
} else {
addEventListener(Event.ENTER_FRAME, onFrame);
event.currentTarget.label = "Stop";
_running = true;
drawLine();
}
}
private function initTags():void {
_graffiti = new Vector.(6, true);
var embeded:Array = [ new GML1(), new GML2(), new GML3(), new GML4(), new GML5(), new GML6() ];
var len:int = embeded.length;
var ba:ByteArray;
for (var i:int = 0; i < len; i++) {
ba = embeded[i] as ByteArray;
ba.position = 0;
_graffiti[i] = new XML(ba.readUTFBytes(ba.length));
}
_colors = new Vector.(6, true);
_colors[0] = 0xFF00FF;
_colors[1] = 0xFF0000;
_colors[2] = 0x00FF00;
_colors[3] = 0x0000FF;
_colors[4] = 0x00FFFF;
_colors[5] = 0xFFFF00;
}
private function nextTag():void {
_gmlNodes = _graffiti[_currentTag]..pt;
_currentPoint = 0;
_zpos = -20;
clearGraphics();
}
private function initGraphics():void {
_s = new Sprite();
_s.filters = [_bayer];
addChild(_s);
_s.visible = false;
_g3d = new Graphics3D(_s);
}
private function clearGraphics():void {
_g3d.clear();
_g3d.lineStyle(6, _colors[_currentTag]);
_g3d.moveTo(_gmlNodes[0].x * _mult, _gmlNodes[0].y * _mult, _zpos);
_tweenobject.x = _gmlNodes[0].x * _mult;
_tweenobject.y = _gmlNodes[0].y * _mult;
_tweenobject.z = 0;
drawLine();
}
private function drawLine():void {
if (!_running) return;
if (_currentPoint + 1 != _gmlNodes.length()) {
var nextPoint:Object = _gmlNodes[_currentPoint + 1];
var t:Number = nextPoint.time - _gmlNodes[_currentPoint].time;
TweenNano.to(_tweenobject, t, { x:nextPoint.x * _mult, y:nextPoint.y * _mult, z:_zpos, onUpdate:updateLine, onComplete:lineComplete } );
} else {
if (++_currentTag == _graffiti.length) _currentTag = 0;
nextTag();
}
}
private function updateLine():void {
_g3d.lineTo(_tweenobject.x, _tweenobject.y, _tweenobject.z);
_zpos += .25;
}
private function lineComplete():void {
_g3d.lineTo(_tweenobject.x, _tweenobject.y, _tweenobject.z);
_currentPoint++;
drawLine();
}
private function onFrame(event:Event):void {
var cx:Number = ((stage.mouseX / stage.stageWidth) - .5) * 2;
var cy:Number = ((stage.mouseY / stage.stageHeight) - .5) * 2;
_g3d.rotateY(cx * -4);
_g3d.rotateX(cy * 4);
_data.applyFilter(_data, _data.rect, _pt, _blur);
_data.draw(_s, null, _darken, BlendMode.ADD);
}
}
}